@ECHO OFF

ECHO THIS SCRIPT IS VERY VERY HACKEY (AND SLOW) AND HAS NO ERROR CHECKING AT ALL!!!
ECHO USE AS A BASIS FOR YOUR OWN SCRIPT ONLY
ECHO DON'T COMPLAIN WHEN IT EATS YOUR CAT

pause

CLS

ECHO Searching for ETC ACN Consoles....


REM Find all ETC Consoles
FOR /f "tokens=1 delims=," %%a IN ('slptool findsrvs service:acn.esta "(acn-fctn=ETC*Console)"') DO (


	FOR /F "tokens=2 delims==" %%b IN ('slptool findattrs %%a acn-fctn') DO (
		REM Show nice name
		<nul SET /p =Device: 
		REM REMOVE TRAILING )
		FOR /F "tokens=1 delims=)" %%c IN ('echo %%b') DO (
			ECHO %%c
		)
	)
	
	FOR /F "tokens=2 delims=/" %%d IN ('slptool findattrs %%a device-description') DO (
		REM Show IP
		<nul SET /p =IP:
		ECHO %%d
	
		FOR /F "tokens=2 delims==" %%e IN ('slptool findattrs %%a acn-uacn') DO (
			REM Console name
			<nul SET /p =Name:
			REM REMOVE TRAILING )
			FOR /F "tokens=1 delims=)" %%f IN ('echo %%e') DO (
				ECHO %%f

				REM Making backup directory (and change into it incase pushd fails)
				mkdir c:\ShowArchive 2>NUL
				mkdir c:\ShowArchive\%%f 2>NUL
				cd C:\ShowArchive\%%f

				REM Mount ShowArchive
				echo Mounting ShowArchive...
				net use \\%%d\ShowArchive "" /USER:ion 2>NUL
				net use \\%%d\ShowArchive  "" /USER:eos 2>NUL
				net use \\%%d\ShowArchive  "" /USER:gio 2>NUL
				net use \\%%d\ShowArchive  "" /USER:ti 2>NUL
				net use \\%%d\ShowArchive  "" /USER:element 2>NUL
			
				REM Open ShowArchive
				echo Open ShowArchive...
				pushd \\%%d\ShowArchive 

	 			REM Backup
				echo Copying ShowArchive to C:\ShowArchive\%%f....
				copy * c:\ShowArchive\%%f
				popd	
			)
		
		)

	)

)

echo ...Done